In de Virtuele Werkplaats
Een Reuleaux model van een vierstangen-mechanisme, Type 2
Het model klaar op de Virtuele Stelplaats
Hier heb je de complete code: Reuleaux_V_4_t_2.scad .... gewoon aanklikken om OpenSCAD te openen.
In andere sessies in de Virtuele Werkplaats hebben we ons al gebogen over het maken van een houten voet, een ijzeren kolom en een klem/spanner. Die onderdelen zijn, toen ze klaar waren, het magazijn "Halfprodukt" ingegaan en nu is het moment aangebroken om ze uit het magazijn te halen en het Reuleaux-model echt samen te stellen. Maar voor we daaraan toe zijn, moeten we dat model zelf nog wel maken ....
Je vindt veel informatie over vierstangen-mechanismen op DEZE pagina. De berekening van een werkend vierstangen-mechanisme vind je op DEZE pagina. Over Reuleaux zelf, en zijn collectie mechanisme-modellen schrijf ik op DEZE set pagina's.
De bouw van het model
Begint vanzelfsprekend in de Virtuele Werkplaats, met de fabricage van de vier stangen. Aangezien we er vier nodig zullen hebben (van verschillende lengte) is het aangewezen om eerst één zo'n stang (parametrisch) als module samen te stellen.
Code:
module Stang (L) {
difference() {
union() {
translate ([0,-6,-2]) cube ([L,12,4]);
translate ([0,0,-3]) cylinder (6,8,8);
translate ([0,0,-3.5]) cylinder (7,4.5,4.5);
translate ([L,0,-3]) cylinder (6,8,8);
translate ([L,0,-3.5]) cylinder (7,4.5,4.5);
}; // einde union
for (i=[0,L]) translate ([i,0,-15]) cylinder (30,3,3);
}; // einde difference
}; // einde module Stang
Elk van de vier hoeken A-B-C-D krijgt een scharnierpen. Ook dat is een module. De variabele X plaatst de pen precies op de juiste diepte in de stangen (die in een 3D model immers dikte hebben).
module Scharnierpen (X) {
translate ([0,0,X]) cylinder (15,3,3);
}; // einde module Scharnierpen
De berekening van het mechanisme gaat samen met het definieren van de vier stangen en de vier scharnierpennen, in een eigen module:
module Vierstangen (AB,BC,CD,DA) {
BD=sqrt(pow(AB,2)+pow(DA,2)-2*AB*DA*cos(phi));
ADB=acos((pow(DA,2)+pow(BD,2)-pow(AB,2))/(2*BD*DA));
BDC=acos((pow(BD,2)+pow(CD,2)-pow(BC,2))/(2*BD*CD));
BCD=acos((pow(BC,2)+pow(CD,2)-pow(BD,2))/(2*BC*CD));
hoek1=-((BCD-180+ADB+BDC));
hoek2=-((BCD-180-ADB+BDC));
color ([0.55,0.58,0.65,1]) rotate ([90,0,0]) {
rotate ([0,0,phi]) Stang (AB);
Scharnierpen (-11);
translate ([0,0,-7.2]) Stang (DA);
translate ([DA,0,0]) Scharnierpen (-11);
if (phi>=0&&phi<=180) {
translate ([DA,0,0]) rotate ([0,0,180-(ADB+BDC)]) {
Stang (CD);
translate ([CD,0,0]) Scharnierpen (-4);
};
translate ([AB*cos(phi),AB*sin(phi),0])
rotate ([0,0,hoek1]) {
translate ([0,0,7.1]) Stang (BC);
Scharnierpen (-4);
};
}
else {
translate ([DA,0,0]) rotate ([0,0,180+(ADB-BDC)]) {
Stang (CD); // CD
translate ([CD,0,0]) Scharnierpen (-4);
};
translate ([AB*cos(phi),AB*sin(phi),0])
rotate ([0,0,hoek2]) {
translate ([0,0,7.1]) Stang (BC);
Scharnierpen (-4);
};
};
}; // einde module Vierstangen
Op de pagina's .... houten voet, .... ijzeren kolom en .... klem en spanner heb ik de code voor die onderdelen beschreven. Dan resteert nu alleen nog het samenstellen van het complete model. Dat doen we op de Virtuele Stelplaats, een aparte afdeling van de Virtuele Werkplaats waar alle 3D machines die ik vervaardig worden samengebouwd, afgesteld en proefgedraaid.
phi=$t*360;
AB=100;
BC=200;
CD=133;
DA=217;
translate ([-DA/2,-14.4,225]) Vierstangen (AB,BC,CD,DA);
translate ([0,0,221]) Spanner_1 (0);
translate ([0,0,221]) Klem_1 ();
translate ([0,0,45]) Kolom (160);
translate ([0,0,0]) Voet ();
Aan de top van deze pagina vind je de totale code van dit complexe model, inclusief alle benodigde onderdelen (modules). Klik daar de link aan en OpenScad opent zich met de code in de Editor. Druk op F5 ("preview") en het model staat op je scherm. Voor het proefdraaien: schakel "View → Animate" in, vul in de Menubalk van het rechtervenster het aantal "Steps" in (zeg, 250) en het aantal "Frames-per-seconde" (FPS, zeg 20). De animatie begint gelijk te lopen, omdat de eerste regel van de code het commando: phi=$t*360; geeft. Één volle omwenteling (360°) vergt bij deze instelling 250/20=12,5 sec.